EarnForex
Software
Scripts para MetaTrader
Cerrar todas las órdenes (posiciones) para MT4 (MT5)

Cerrar todas las órdenes/posiciones para MT4/MT5

Contenido

Cerrar todas las órdenes con MQL4
Cerrar todas las posiciones con MQL5
Conclusión
Discusión
Registro de cambios

Contenido

La gestión de las órdenes es una tarea fundamental cuando se trabaja con herramientas de trading y asesores expertos. En algunos casos, especialmente cuando hay un desencadenante de alguna regla de gestión de riesgos, es posible que desee cerrar todas las órdenes abiertas. Aquí, examinaremos dos funciones (una en código MQL4 y otra en código MQL5) para hacer eso, y también podrá descargar un script gratuito para cerrar todas las órdenes en MT4 (un script que puede cerrar todas las órdenes abiertas automáticamente). Un script similar llamado Cerrar todas las posiciones también está disponible para MetaTrader 5.

Cerrar todas las órdenes con MQL4

Al programar un asesor experto, todos deberíamos aplicar medidas de seguridad para protegernos de grandes pérdidas. La gestión del riesgo es un pilar fundamental de un EA. Es necesario establecer reglas para que su EA pueda cerrar todas las órdenes si se cumple alguna condición.

Algunos ejemplos que podrían desencadenar el cierre de todos las órdenes pueden ser:

Un grupo de órdenes alcanzó el take-profit.
La pérdida acumulada de las órdenes abiertas hace que el patrimonio o el margen se sitúen por debajo de un umbral específico.
Está prevista la publicación de un informe que podría tener un fuerte impacto en los precios.
Un acontecimiento inesperado provoca cambios bruscos en los tipos de cambio.

Estas son solo algunas situaciones que pueden empujarle a cerrar todas las órdenes abiertas inmediatamente. Esto se consigue con un sencillo fragmento de código MQL4.

Probablemente ya ha leído nuestra guía sobre la función OrderClose, que puede cerrar una orden en concreto en MT4. A continuación, puede ver cómo utilizarla para cerrar todas las órdenes con una función personalizada.

La siguiente función en MQL4 para cerrar todas las órdenes puede cerrar todas las órdenes a mercado abiertas en la misma ejecución.

void CloseOrders()
{
   int total = OrdersTotal();
   // Registrar en el terminal el número total de órdenes.
   Print(total);
      
   // Iniciar un bucle para escanear todos las órdenes.
   // El bucle empieza por la última, de lo contrario podría saltarse órdenes.
   for (int i = total - 1; i >= 0; i--)
   {
      // Si la orden no puede ser seleccionada, lanza y registra un error.
      if (OrderSelect(i, SELECT_BY_POS) == false)
          {
         Print("ERROR - No se ha podido seleccionar la orden - ", GetLastError());
         break;
      } 

      // Variable resultado: para comprobar si la operación se ha realizado correctamente o no.
      bool result = false;
      
      // Actualizar los tipos de cambio antes de cerrar las órdenes.
          RefreshRates();

      // Precio de compra y venta para el símbolo de la orden.
      double BidPrice = MarketInfo(OrderSymbol(), MODE_BID);
      double AskPrice = MarketInfo(OrderSymbol(), MODE_ASK);

      // Cerrar la orden utilizando el precio correcto en función del tipo de orden.
      if (OrderType() == OP_BUY)
          {
         result = OrderClose(OrderTicket(), OrderLots(), BidPrice, Slippage);
      }
      else if (OrderType() == OP_SELL)
          {
         result = OrderClose(OrderTicket(), OrderLots(), AskPrice, Slippage);
      }
      
      // Si hubo un error, registrarlo.
      if (!result) Print("ERROR - No se ha podido cerrar la orden - ", OrderTicket(), " - Error ", GetLastError());
   }
}

Lógica de funcionamiento al cerrar todas las órdenes con MQL4

La lógica de la función es la siguiente

Utilizando un bucle, escanea todos las órdenes.
Actualiza los precios.
Si el tipo de orden es de compra o venta a mercado, cierra la orden utilizando el precio correcto.
Comprobar si la operación se ha realizado correctamente para cada orden y, en caso contrario, devolver un error.

Posibles mejoras

La función no es muy compleja y puede mejorarse con filtros adicionales. Por ejemplo, puede que desee aplicar alguno de los siguientes filtros:

Cerrar solo las órdenes con beneficios.
Cerrar solo las órdenes con pérdidas.
Cerrar solo las órdenes de un par en concreto.
Cerrar solo las órdenes con un número mágico específico.
Otros filtros.

La función anterior, en una forma algo modificada, es utilizada por muchos de nuestros asesores expertos.

Script para cerrar todas las órdenes

Si desea cerrar todas las órdenes en MT4, debe hacerlo manualmente, a menos que utilice una herramienta externa.

Desafortunadamente, MT4 no permite seleccionar todas las órdenes abiertas y cerrarlas todas a la vez.

¡Pero hay una solución! Puede programar su propio script utilizando la función anterior como plantilla o puede utilizar una herramienta ya creada.

El script que se proporciona a continuación se puede copiar en su plataforma de MT4 y le permitirá cerrar todas las órdenes con solo un par de clics.

Hay una serie de parámetros de entrada para configurar el script según sus preferencias:

Además de los parámetros de filtrado, existe la opción de ordenar las órdenes antes de cerrarlas en un orden determinado. Esto le permite optar por cerrar primero las órdenes de mayor prioridad.

Una opción interesante es establecer un retraso (en milisegundos) entre los intentos de cierre para evitar sobrecargar el servidor de trading, ya que algunos brókeres de Forex no permiten tal comportamiento y pueden bloquear el trading automático en su cuenta.

También puede controlar el número de intentos que realizará el script para cerrar cada orden. Esto permite asegurar el cierre adecuado de las operaciones incluso durante periodos de alta volatilidad, cuando una orden de cierre al servidor puede fallar debido a algún error.

Descargar el script Cerrar todas las órdenes para MT4

➥ Descargar Cerrar todas las órdenes para MT4Descargas

Instalación del script para cerrar todas las órdenes en MT4

Para instalar el script, siga las siguientes instrucciones:

Descargue el archivo del script.
Abra la carpeta de datos de MetaTrader 4 (mediante Archivo→Abrir carpeta de datos).
Abra la carpeta MQL4.
Copie todas las carpetas del archivo directamente en la carpeta MQL4.
Reinicie MetaTrader 4 o actualice la lista de scripts haciendo clic derecho en la subventana Navegador de la plataforma y seleccionando Actualizar.

También puede leer unas instrucciones más detalladas sobre cómo realizar la instalación.

Asegúrese de activar permitir el comercio algorítmico o Live Trading en la pestaña Común al ejecutar este script y también en el menú de la plataforma Herramientas→Opciones→Asesores Expertos. De lo contrario, no podrá cerrar ninguna orden.

Parámetros de entrada preintroducidos

Puede introducir previamente los valores de los parámetros de entrada del script Cerrar todas las órdenes y, a continuación, guardar una copia con un nombre de archivo diferente para utilizar scripts preconfigurados siempre que los necesite sin necesidad de dedicar tiempo a la modificación de los parámetros de entrada.

De esta forma, tendrá a mano varios scripts listos para ser ejecutados (mediante un atajo de teclado, por ejemplo) en función de la situación.

Por ejemplo, hagamos una versión para cerrar solo todas las operaciones perdedoras.

Primero, necesita abrir el archivo CloseAllOrders.mq4 y localizar el parámetro de entrada OnlyInLoss:

Ahora, cambie el valor por defecto de false a true:

También tiene sentido eliminar por completo la propiedad show_inputs en una versión preconfigurada. Esto evitará que aparezca la ventana de confirmación al iniciar el script:

La línea puede comentarse (con dos barras delante) o eliminarse por completo:

Ahora puede guardar el archivo con otro nombre para distinguirlo del script "Cerrar todas las órdenes" estándar. Por ejemplo, puede llamar a este CloseAllOrders_Losing.mq4:

Ahora es el momento de compilar el código fuente:

Ahora puede ejecutar el nuevo script como de costumbre en su MetaTrader 4 o puede hacer clic derecho sobre él y establecer una tecla de acceso rápido:

Ahora puede ejecutar este script al instante para cerrar órdenes filtradas según sus requisitos específicos lo más rápidamente posible.

Un proceso similar puede repetirse para crear scripts que cierren solo órdenes de compra o solo órdenes de venta, o un script que cierre solo órdenes con un número mágico en concreto (si necesita cerrar solo operaciones abiertas por algún EA), etc.

Cerrar todas las posiciones con MQL5

El concepto de una función que cierra todas las operaciones en MetaTrader 5 no es muy diferente de la de MetaTrader 4. La principal diferencia es que las órdenes de mercado se llaman posiciones en MT5.

Esta función de cierre de posición se puede utilizar en las mismas situaciones en las que utilizaría la función de cierre de órdenes en MetaTrader 4.

El siguiente código en MQL5 para cerrar todas las posiciones está diseñado para eliminar todas las posiciones existentes en una sola ejecución.

void ClosePositions()
{
   Trade = new CTrade; // Un objeto CTrade para cerrar posiciones.
   int total = PositionsTotal();
   // Registra en el terminal el número total de posiciones.
   Print(total);
      
   // Inicia un bucle para escanear todas las posiciones.
   // El bucle empieza por la última, de lo contrario podría saltarse posiciones.
   for (int i = total - 1; i >= 0; i--)
   {
      // Si la posición no puede ser seleccionada, lanza y registra un error.
      if (PositionGetSymbol(i) == "")
          {
         Print("ERROR - No se ha podido seleccionar la posición - ", GetLastError());
         break;
      } 

      // Variable resultado: para comprobar si la operación se ha realizado correctamente o no.
      bool result = Trade.PositionClose(PositionGetInteger(POSITION_TICKET), Slippage);
      
      // Si hubo un error, registrarlo.
      if (!result) Print("ERROR - No se ha podido cerrar la posición - ", PositionGetInteger(POSITION_TICKET), " - Error ", GetLastError());
   }
}